Отправляет email-рассылки с помощью сервиса Sendsay

Советы по Delphi

Рассылка закрыта

При закрытии подписчики были переданы в рассылку "Delphi - проблемы и решения" на которую и рекомендуем вам подписаться.

Вы можете найти рассылки сходной тематики в Каталоге рассылок.

←   Апрель 2001   →
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Автор
Сергей

Статистика

13.545 подписчиков
-22 за неделю
←   Все выпуски   →

Советы по Delphi


Служба Рассылок Subscribe.Ru проекта Citycat.Ru
Преобразование числа в текст

Здравствуйте, уважаемые подписчики! Сегодня поговорим о том, как преобразовывать целые числа в слова (12345 - "двенадцать тысяч триста сорок пять").

Поскольку, произнося числа, мы делим их на разряды по три цифры в каждом, то для преобразования чисел в слова нужно создать функцию, которая бы переводила трехзначное число в текст. В нескольких массивах записаны слова, обозначающие сотни, десятки, единицы и числа от 11 до 19. Из них составляется текст. Функция должна также учитывать род: "один миллион" и "одна тысяча". К числу прибавляется "тысяча" или "миллион" и т.д.

Для преобразования всего числа нужно вызвать эту функцию для каждых трех цифр в числе и сложить результаты. 

const
  hundreds: array [0..9] of string = ('', ' сто', ' двести', ' триста',
    ' четыреста', ' пятьсот', ' шестьсот', ' семьсот', ' восемьсот',
    ' девятьсот');
  tens: array [0..9] of string = ('', '', ' двадцать', ' тридцать',
    ' сорок', ' пятьдесят', ' шестьдесят', ' семьдесят', ' восемьдесят',
    ' девяносто');
  ones: array [3..19] of string = (' три', ' четыре', ' пять', ' шесть',    ' семь', ' восемь', ' девять', ' десять', ' одиннадцать',
    ' двенадцать', ' тринадцать', ' четырнадцать', ' пятнадцать',
    ' шестнадцать', ' семнадцать', ' восемнадцать', ' девятнадцать');
  razryad: array [0..6] of string = ('', ' тысяч', ' миллион', ' миллиард',
    ' триллион', ' квадриллион', ' квинтиллион');

function ShortNum(num: word; razr: integer): string;
var
  t: byte; // десятки
  o: byte; // единицы
begin
  result := hundreds[num div 100];
  if num mod 100 = 0 then Exit;
  t := (num mod 100) div 10;
  o := num mod 10;
  if t <> 1 then begin
    result := result + tens[t];
    case o of
      1: if razr = 1
        then result := result + ' одна'
        else result := result + ' один';
      2: if razr = 1
        then result := result + ' две'
        else result := result + ' два';
      3..9: result := result + ones[o];
    end;
    result := result + razryad[razr];
    case o of
      1: if razr = 1 then result := result + 'а';
      2..4: if razr = 1
        then result := result + 'и'
        else if razr > 1 then result := result + 'а';
      else if razr > 1 then result := result + 'ов';
    end;
  end else begin
    result := result + ones[num mod 100];
    result := result + razryad[razr];
    if razr > 1 then result := result + 'ов';
  end;
end;

function IntToWords(s: string): string;
var
  i, count: integer;
begin
  if Length(s) <= 0 then begin
    result := 'ноль';
    Exit;
  end;
  count := (Length(s) + 2) div 3;
  if count > 7 then begin
    result := 'Value is too large';
    Exit;
  end;
  result := '';
  s := '00' + s;
  try
    for i := 1 to count do
      result := ShortNum(StrToInt(copy(s, Length(s) - 3 * i + 1, 3)), i - 1) + result;
    if Length(result) > 0 then delete(result, 1, 1);
  except
    result := 'Error';
  end;
end;

procedure TForm1.Edit1Change(Sender: TObject);
begin
  Edit2.Text := IntToWords(Edit1.Text);
end;

Всего доброго,
Даниил Карапетян.

На сайте http://delphi4all.narod.ru Вы найдете еще более 100 советов по Delphi.
Email: delphi4all@narod.ru

http://subscribe.ru/
E-mail: ask@subscribe.ru
В избранное