Рассылка "Создание игр на Flash MX"
КРУПНО: Для тех, кто подписался недавно, советую прочитать FAQ
Архив рассылки http://subscribe.ru/archive/comp.soft.prog.makeflashgame/

Приветствую всех новых подписчиков. Надеюсь, что барьер в 2000 будет скоро взят и я из узковещательного перейду в широковещательный формат;)))

Поясню, что здесь происходит: в каждом номере (ну, почти в каждом;) я стараюсь выложить и описать 1 игру.

Сегодня это текстовый квест. Результаты голосования показали, что против нет никого, а вот за квест проголосовало 10(!) человек, за что им всем персональное спасибо. Как-то неактивоно вы все голосуете, господа подписчики...Ну да ладно, в этом номере - начало первой части текстового квеста... (Вчера весь день убил на перевод qst во Флэш...сделал только половину... Вот такое это нелегкое и неблагодарное дело... квесты писать...А вы как думали? Может сегодня допишу...Порадую к понедельнечку...)

Сегодня делаем ТЕКСТОВЫЙ КВЕСТ.

Квест "Побег" написан замечательным квестописателем и просто хорошим человеком Mishgan -ом. На его домашней страничке http://rkp.narod.ru/ можно найти 2 замечательных квеста: "Побег" и "Полет гарпии". Написаны они для специального интерпритатора квестов URQ. Всю информацию про текстовые квесты и разнообразные интерпретаторы можно найти в Сети. Пароль для Яндекса - "текстовый квест" ;)

Квест написан для специального интерпритатора, что, в некотором роде, облегчит перевод его во Флэш. Но не надейтесь, что все будет так просто. Во Флеше очень неразвиты команды работы с файлами. Что ограничивает его использование. Но мы же не пишем интерпритатор, верно? Мы пишем текстовый квест в единственном варианте, поэтому мы вошьем текст в код. Приведу полностью квест "Побег" как он написан в файле escape.qst (желающие посмотреть оригинал, могут обратиться на страницу автора http://rkp.narod.ru/):

========================================начало=============================================

:intro
pln Здравствуйте все!
pln
pln
pln Рад представить вашему вниманию игру
pln
pln ПОБЕГ-остаться в живых ver 1.02
pln
pln Mishgan 2002
btn 3, Играть!!!
btn 1, Вступление
btn 2, Спасибо
end

:1
pln Вместе со своими двумя братьями и дедом ты жил у подножия Северных гор недалеко от деревни Рыболовной. Название своё она получила не зря - в этом районе море действительно богато рыбой. Жители деревни, как и ваша семья, ловили рыбу, которую затем меняли у приезжающих купцов на другие товары. Но была и одна проблема - гоблины, живущие в горах. До вчерашнего дня их отгонял от поселения людей твой дед - довольно неслабый волшебник, в молодости состоявший даже какое-то время в гильдии магов. Но он умер, и в рядах людей началась паника, они начали собирать вещи и уезжать. И вот, заснув вечером на своей кровати, ты просыпаешься в сыром подвале своего дома. Ничего не понимая, ты открываешь глаза и встаешь...
btn intro, Назад
end

:2
pln Viktor'у и RipOs'у - за квеcтовые платформы
pln Кащею - за лучший сайт о текстовых играх http://textquest.boom.ru
pln Авторам игр
pln Всем-всем любителям русского IF
btn intro, Назад
end

:3
pln Ты полностью просыпаешься и понимаешь, что это не сон и ты действительно в подвале своего дома. Необходимо разобраться, в чем дело и как ты сюда попал.
goto 4
end

:4
pln Ты находишься в сыром подвале. В стене находится деревянная, оббитая железом дверь, через которую можно попасть в кухню, другая дверь ведет в кладовку. На стенах полки, на которых обычно лежат всякие разности. На стене горит огарок свечи, скудно освещающий подвал. На полу валяются мелкие камешки. В углу лежат доски. У стены лежит громадный камень, на который наткнулись при выкапывании подвала и так и не смогли выкатить наверх.
if zapiska=0 then p В свете свечи ты замечаешь клочок бумаги, валяющийся на полу. & btn 5, Поднять бумажку
btn 6, Осмотреть камень
btn 7, Осмотреть полки
btn 8, Взять доску
btn 9, Идти в кладовку
btn 4a, Идти в кухню
end

:4a
if kuhnaotkrita=1 then pln Ты поднимаешься в кухню & goto kit
if kuhnaotkrita=0 then pln Ты подходишь к массивной железной двери. Она заперта.
if Топор and kuhnaotkrita=0 then btn 4b, рубить дверь топором
btn 4, Отойти от двери
end

:4b
if rubleno=0 then goto 4c
if rubleno=1 then goto 4d
end

:4c
pln Ты некоторое время рубишь неподдающуюся дверь и затем понимаешь бессмысленность своих действий. & rubleno=1
btn 4a, Дальше
end

:4d
pln Ты уже один раз убедился, что это бессмысленно.
btn 4a, Дальше
end

:5
zapiska=1
pln Ты поднимаешь бумажку и замечаешь, что на ней что-то написано. Вспоминая дедовы уроки чтения, ты начинаешь читать.
pln
pln "Дорогой брат!
pln Извини, что нам пришлось бросить тебя здесь, но у нас не было другого выбора. У троллей появился могущественный колдун, усеявший все пространство вокруг Рыболовной волшебными ловушками. В союзе с гоблинами они разрушают деревню и скоро доберутся до нашего дома. Мы решили уплыть на нашей лодке, но в ней только два места. Прощай."
pln Теперь ситуация стала проясняться. Судя по полоске света под дверью, сейчас день. Минувшей ночью гоблины напали на деревню и разорили её, а твои братцы, испугавшись, уплыли. Ну что же, во всяком случае, у тебя есть еще время до того, как стемнеет.
btn 4, Дальше
end

:6
pln Большой камень. В детстве ты думал, что под ним хранятся сокровища. Хотя даже если это было бы и так, то ты все равно не смог бы его сдвинуть с места.
if Молот then btn 6a, Бить по камню молотом
btn 4, Дальше
end

:6a
pln Ты размахиваешься (насколько это позволяет низкий потолок подвала) и ударяешь молотом по камню, затем ещё и ещё.
pln Отложив орудие в сторону, ты исследуешь результат работы. Ничего-ни малейшей трещинки.
kirpich=1
btn 4, Дальше
end

:7
if polka=0 then pln Ты шаришь по неосвещенным свечкой полкам. & pln ЧЕРТ! & pln Ты порезался об лежащий на полке остро отточенный топор. Недолго думая, ты берешь его себе. & inv+ Топор & p Кроме него, & polka=1
pln на полке ты ничего не обнаружил. Видимо, все забрали твои братцы.
if Молот then btn 7a, Положить молот
if molot=2 then btn 7b,Взять молот & pln На полке лежит молот
btn 4, Дальше
end

:7a
inv- Молот
pln Пусть полежит пока здесь.
molot=2
btn 7, Дальше
end

:7b
pln Ты берешь молот с собой.
inv+ Молот
molot=1
btn 7, Дальше
end

:8
if not doska=0 and Доска then pln Ты не унесшь две доски сразу-они довольно большие и широкие.
if doska=0 then pln Ты берешь доску & inv+ Доска & doska=1
if doska=1 and not Доска then pln Ты берешь вторую доску и замечаешь, что под ней лежало несколько гвоздей. & inv+ Доска & inv+ Гвозди & doska=2
if doska=2 and not Доска then pln Ты берешь доску & inv+ Доска
btn 4, Дальше
end

:9
if dverklad=0 then goto 9a
if dverklad=1 then goto 10
end

:9a
pln Ты дергаешь дверь за ручку, и она оказывается закрытой.
if Топор then btn 9b, Рубить дверь
btn 4, Дальше
end

:9b
dverklad=1
pln После 15 минут упорного труда дверь наконец-то распахивается.
btn 10, В кладовку
btn 4, Дальше
end

:10
pln Ты в кладовке. Эта маленькая комнатка находится ниже, чем предыдущая. У стены стоит большая картина неизвестного художника, прислонённая лицевой стороной к сырым кирпичам. В дальнем углу стоит бочка с вином, с потолка свисают несколько кусков вяленного мяса.
btn 10a, Осмотреть бочку
btn 10c, Осмотреть мясо
btn 11, Осмотреть картину
btn 4, В подвал
end

:10a
pln Большая бочка, в которой много вина.
btn 10b, Пить вино
btn 10, Назад
end

:10b
if drunk<3 then goto 10ba
if drunk=3 then goto 10bb
end

:10ba
pln Ты выдергиваешь деревянную пробку и делаешь несколько больших глотков. В голове немного мутит.
drunk=drunk+1
btn 10a, Дальше
end

:10bb
pln Ты делаешь несколько больших глотков. В глазах темнеет, и ты падаешь на пол, не замечая, как наступает ночь и твой дом разрушают гоблины, хороня тебя под обломками.
end

:10c
pln Купленное у купца мясо на зиму. Попытки откусить хотя бы кусочек ни к чему не приводят.
if Нож then btn 10d, Отрезать кусок мяса ножом
btn 10, Назад
end

:10d
if not Мясо and not Собака then pln Ты отрезаешь большой кусок мяса от туши и кладешь в карман & inv+ Мясо
if Собака or Мясо then pln Зачем тебе еще один кусок?
btn 10, Отойти от мяса
end

:11
pln Ты отодвигаешь картину в сторону.
if molot=0 then p Под ней ты замечаешь лежащий на полу кузнечный молот & btn 11a, Поднять молот
if laz1=0 then btn 11b, Исследовать стену
btn 11aa, Поставить картину на место
if laz1=1 then btn 12, Лезть в лаз
end

:11aa
pln Ты ставишь картину на место.
goto 10
end

:11a
molot=1
pln Ты поднимаешь молот с пола. Видимо, он принадлежал твоему деду, кузня которого находилось точно над этим местом.
inv+ Молот
btn 11, Дальше
end

:11b
if stena=0 then goto 11c
if stena=1 then goto 11d
if stena=2 then goto 11e
end

:11c
pln Ты не замечаешь ничего необычного.
stena=1
btn 11, Дальше
end

:11d
pln Прощупав каждый кирпич, ты всё равно ничего не находишь.
stena=2
btn 11, Дальше
end

:11e
if kirpich=0 then pln Ты окончательно убедился, что ничего необычного нет. & stena=0
if kirpich=1 then pln Тщательно все осмотрев, ты всё-таки замечаешь один чуть выступающий кирпич (видимо, его расшатали твои удары по камню). Тебе удается вынуть его и разобрать кусок стены. За ним ты находишь пустоту и забираешься туда. & goto12 & laz1=1
btn 11, Дальше
end

:12
pln Ты находишься в узкой комнатке. Видимо, раньше здесь стояла лестница, и по ней твой дед мог лазить из кузницы в кладовку.
if laz=1 then btn 12a, Вылезти наружу
if laz=0 then p Когда ты залезаешь вовнутрь, часть земли с потолка осыпается и открывается выход на поверхность. & btn 12a, Вылезти наружу
btn 10, В кладовку
end

:12a
if Молот then pln Ты пытаешься выкарабкаться на поверхность, но у тебя ничего не получается. & btn 12, Назад
if not Молот then pln Ты подтягиваешься и оказываешься на поверхности. & goto 13
end

:13
pln Ты находишься на развалинах старой дедовской кузни. Сейчас от неё остался один фундамент. В земле зияет проделанный тобой лаз в подвал. С востока надвигаются горы, покрытые снежными куполами. Рядом с развалинами твой дом, можно пойти на причал.
btn 12, Лезть вниз
btn 14, Идти во двор дома
btn kit, зайти в дом
btn 15, Идти на причал
end

:14
pln Ты во дворе своего дома. Немного запущенный, сад все же не потерял своей привлекательности. Под большой яблоней любил сидеть твой дед, рассказывая о ратных подвигах далекого прошлого, а ты сидел рядом, раскрыв рот и слушая о поединках доблестных рыцарей с драконами и о бесконечных междоусобных баталиях гоблинов. Но эти времена прошли, и сейчас некогда предаваться воспоминаниям.
pln Здесь же стоит колодец с чистой водой.
btn 16, Залезть на дерево
btn 14b, Пить воду
btn 13, Идти к развалинам кузни
end

:14b
pln Ты пьешь воду из колодца
save 14
btn 14, Обратно
end

:15
pln Ты подходишь к причалу. Тут обычно стояла ваша с братьями лодка, но сейчас ее нет. Она уплыла, и, наверное, никогда уже не приплывет.
pln Ты cмотришь на тонкую полоску земли на горизонте. Тебе необходимо уплыть туда до вечера, если ты не хочешь погибнуть от клыков и ржавых гоблинских ножей... Но лодки нет, да и представление о том, как ее сделать, ты не имеешь... В нерешительности ты отходишь от морского берега.
if kluchkit=0 then pln Ты видишь железный ключ, лежащий недалеко от твоих ног & btn 15a, Взять ключ
if not Собака then p Около пристани ты видишь громадного пса, спящего на песке. Видимо, он принадлежал кому-то из твоих соседей, а они оставили его, уплывая. Странно, что ты никогда не видел его раньше. & btn 15b, Подойти к собаке
btn 13, Идти к развалинам кузни
end

:15b
pln Ты подбираешься к спящему псу. При твоем приближении он поднимает голову и рычит.
if Мясо then btn 15c, Кинуть псу мясо
btn 15, Отойти от собаки
end

:15c
pln Пес ловит мясо на лету и машет тебе хвостом. Теперь он пойдет с тобой.
inv- Мясо
inv+ Собака
pln Когда пес встает с земли, ты замечаешь лежавшее под ним огниво - два скрепленных друг с другом кремня.
inv+ Огниво
btn 15, Дальше
end

:15a
pln Ты поднимаешь ключ с земли и кладешь его себе в карман.
inv+ Ключ
kluchkit=1
goto 15
end

:16
pln Ты ловко забираешься на дерево, и через несколько секунд ты уже наверху, осматривая окрестности.
pln Солнце уже торопится завершить свой дневной путь, скоро начнет смеркаться и изо всех щелей полезет нечисть. Ты решаешь поторопиться и спрыгиваешь с дерева.
btn 14, Дальше
end

:kit
pln Ты заходишь в дом, в котором ты прожил всю свою жизнь. Крепкие дубовые стены завершаются тупоугольным сводом соломенной крыши. На стенах висят полки, на которых расставлена нехитрая деревянная посуда. Несколько стульев за крепким столом. Каменная печь в углу. В стене дверь в жилую комнату.
btn 17, Осмотреть печь
btn 18, Осмотреть полки
btn 19, Идти в комнату
btn 13, Выйти из дома
btn kit2, Спускаться в подвал
end

:kit2
if kuhnaotkrita=1 then pln Ты спускаешься в погребок & goto 4
if kuhnaotkrita=0 and not Ключ then pln Ты стоишь у железной двери и не знаешь, как её открыть & goto kit
if kuhnaotkrita=0 and Ключ then pln Ты стоишь у железной двери и не знаешь, как её открыть & btn kit2a, Попробовать ключом & btn kit, Не пробовать
end

:kit2a
pln Ты проворачиваешь ключ, и дверь со скрипом открывается
kuhnaotkrita=1
inv- Ключ
btn 4, Дальше
end

:17
if Уголек then pln Зачем тебе еще один уголек?
if not Уголек then pln В печи ты обнаруживаешь несколько угольков и решаешь взять один себе. & inv+ Уголек
if Доска and Огниво and Топор and ogon=0 then btn 17a, Разжечь огонь.
btn kit, оставить печь в покое.
end

:17a
pln Ты рубишь доску топором в щепки, затем аккуратно собираешь щепки в печь и чиркаешь над ними огнивом. Огонь весело поедает топливо, отбрасывая блики на стены.
inv- Доска
ogon=1
doska=1
btn kit, Дальше
end

:18
pln Ты шаришь рукой по полкам, задеваешь деревянную плошку и она падает под стол.
btn 18a, Поднять плошку
end

:18a
if ogon=1 and not Бумага с рисунком then pln Ты залезаешь под стол и, помимо плошки, видишь там кусок бумаги с непонятным символом - наверное, он принадлежал твоему деду. Хотя значение рисунка тебе неизвестно, ты решаешь взять клочок с собой & inv+ Бумага с рисунком
if ogon=0 then pln Ты на ощкпь находишь плошку и ставишь ее на место.
goto kit
end

:19
pln Ты заходишь в вашу с братьями комнату. Абсолютно ничего лишнего - просто три лежанки.
btn 19a, Прилечь
btn kit, Идти в кухню
btn 20, Идти в дедову комнату
end

:19a
if Нож then pln Ты пять минут дремлешь и затем поднимаешься, чувствуя немного новых сил. & btn 19, Дальше
if not Нож then pln Ты прилег и почуствовал укол в бок. & btn 19b, Посмотреть & btn 19, Вскочить с лежанки
end

:19b
pln Ты запускаешь руку под тюфяк и находишь нож своего брата.
inv+ Нож
btn 19, Дальше
end

:20
pln Ты заходишь в комнату своего деда - самую таинственную в доме. Он никогда никого не пускал сюда, но сам просиживал здесь часами, изготовляя магические элексиры и практикуясь в магии. Но сейчас почти все перевернуто и разбито твоими братьями - наверное, искали дедовы деньги. Впрочем, кое-что вроде осталось. На столе стоит непонятная установка, состоящая из двух соединенных перпендикулярно дощечек, исписанных рунами. На нижней нарисован квадрат.
pln Это единственная комната в доме, где есть окно. Оно обычно закрыто ставнями, но сейчас они отломаны и унесены в неизвестном направлении.
pln Немного поразмыслив, ты решаешь укреплять эту комнату и принять здесь неравный бой.
btn 20a, Исследовать полки на стене
btn z, Исследовать установку
btn 21, Исследовать окно
btn 22, Ждать наступления ночи
btn 19, Идти в комнату
end

:20a
pln С полок, некогда уставленных плошками с микстурами, сметено абсолютно все.
btn 20, Назад
end

:z
pln Ты подходишь к странной деревяшке и совершенно не знаешь, для чего она
if Уголек and Бумага с рисунком then btn 20f, Нарисовать угольком иероглиф
btn 20, Назад
end

:20f
pln Ты достаешь бумагу и тщательно копируешь иероглиф в пустой квадрат на нижней дощечке. Как только иероглиф нарисован, бумага вспыхивает и мгновенно сгорает. В воздухе появляется зеркальная прозрачная сфера, в которой проявляются лица каких-то людей.
inv- Бумага с рисунком
btn t1, Дальше
end

:t1
pln "Кто ты такой и зачем вызываешь нас?!"-грозно спрашивает самый молодо выглядящий из них
btn t2, "Я внук Делларда, и мне нужна помощь"
btn t2, "Извините, я попал к вам по ошибке"
end

:t2
pln "Ну конечно! Это же внук моего друга Делларда! Как твой дед, сынок? И почему ты активизировал дедов портал связи?"-восклицает старичок слева
pln "Он мертв. А вызвал я вас потому, что если мне не помогут, меня съедят гоблины. Они уже почти сожгли деревню и сегодня придут ко мне."
pln "Где ты?"
pln "Я в доме моего деда."
pln "Держись. Я уже выслал к тебе лодки."
pln Портал закрывается так же внезапно, как и появился.
vizov=1
btn 20, Дальше
end

:21
if oknozabito=1 then goto 23
pln Ты выглядываешь в окно. Гоблин легко может через него пролезть.
if Доска and Гвозди and Молот then btn 24, Забить окно доской
btn 20, Назад
end

:23
pln Ты еще раз проверяешь прочность окна. Все в норме
btn 20, Дальше
end

:24
pln Ты приставляешь доску к окну и накрепко вбиваешь гвозди по шляпку.
inv- Доска
inv- Гвозди
oknozabito=1
btn 20, Дальше
end

:22
if not Собака then pln Ты не справишься один. Тебе надо найти еще кого-нибудь. & goto 20
if oknozabito=0 then pln Ничего не получится. Гоблины пролезут в комнату через окно и тогда ты пропал. & goto 20
if vizov=0 then pln Ты не сможешь продержаться всю ночь! Тебе надо вызвать подмогу. & goto 20
if Собака and oknozabito=1 and vizov=1 then goto 25
end

:25
pln Ты вынимаешь из-за спины топор и ждешь наступления темноты.
btn 26, Ждать
end

:26
pln Сгущаются сумерки. Сначала где-то далеко раздается вой волколаков-неизменные спутники гоблинов, почувствовавшие добычу в деревне. Затем уже ближе раздаются боевые крики гоблинов. И вот уже кто-то распахивает дверь твоего дома. Ты замираешь за дверью не дыша, крепче сжимая топор в руке и молясь всем известнвм тебе богам. Пес сидит рядом, навострив уши. И вот дверь в комнату распахивается и ты видишь руку гоблина, сжимающую ржавый меч.
btn 27, Ударить топором
end

:27
pln Ты рубишь топором голову гоблина, и он падает замертво, издав душераздирающий вопль. Ты слышишь топот сотен ног, бегущих
к твоему дому.
pln Гоблины скребут стены, заколоченное окно, наваливаются через дверь. Ты без устали работаешь топором, как-то увертываясь от вражеских клинков, но перевес на их стороне. И вот, когда падает замертво проткнутый кинжалом пес, перегрызший не один десяток гоблинских шей, и у тебя уже не остается надежды, в толпу врагов врезается огненный шар, разбрасывая куски паленого мяса, и с улицы раздается крик "Сюда!! Скорее!!"
btn 29, Постараться выбраться на улицу
btn 28, Остаться в комнате
end

:28
pln Ты посепенно отступаешь. И вдруг в тебя втыкается меч, затем еще и еще. В глазах темнеет от боли и ты падаешь на пол.
end

:29
pln Ты предпринимаешь отчаянный рывок, и вот ты уже на улице.
pln Ты видишь старичка из портала и несколько рыцарей, бьющихся с гоблинами.
pln "Прыгай в лодку, мы сейчас!!"-кричит тебе старик. Ты бежишь на пристань и запрыгиваешь в лодку.
pln
pln
pln Ты оглядываешься и видишь, что почти все рыцари уже мертвы. Можно попытаться помочь оставшимся, но что вы можете сделать против орды гоблинов?
btn 30, Броситься на помощь
btn 31, Отплывать
end

:30
pln Ты бежишь по направлению к рыцарям, но в твою голову попадает камень из пращи. Ты теряешь сознание-и уже навсегда.
end

:31
pln Ты отчаливаешь и отгребаешь от берега-и вот ты уже в безопасности. Ты держишь путь в ту страну за морем, куда, наверное, уплыли твои братья, где нет еще гоблинов и где еще можно жить.
btn 32, Конец
end

:32
pln Мои поздравления!!!
pln Надеюсь что вам понравилось.
pln Если есть желание, напишите отзыв на
pln mishgandoom@rambler.ru
pln -буду рад.
pln Михаил Евдокимов aka Mishgan
pln Санкт-Петербург 2002

========================================конец=============================================

Видите, все достаточно просто в смысле программирования. Исходник, конечно придеться переделать. И основательно, скажу я вам. Вы пока разберитесь, что как работает.

Продолжение - в следующем выпуске... Нужно подумать, как это все обставить, чтобы глазу приятно и вообще....

Если кому-то интересно посмотреть рабочий вариант уже переведенного квеста - берите его как всегда на моем сайте http://mite.by.ru/txtquestv3.rar На самом сайте ссылки нет, так что пока только вы знаете, что получиться. Советы по игре принимаются и приветствуются... Может кто изменит дизайн квеста, сделает его лучше, приятней и удобней? За что буду благодарен и помещу официальный регардз...

Принимается помощь в переводе из qst во Флэш. Что-то мне уже надоелло, если честно;))).

Ваши предложения, пожелания, критика и прочее всегда принимаются по адресам

mailto:mitemail@mail.ru
ICQ: 168070919

И будьте чуточку активней!

____________________________________________________________

С уважением, mite.

http://mite.by.ru/
mailto:mitemail@mail.ru
ICQ 168070919

Для тех, кто подписался недавно, советую прочитать FAQ.
Архив рассылки http://subscribe.ru/archive/comp.soft.prog.makeflashgame/